program Rei;
               (* 〜　〜 *)
               (* ｏＹｏ *)
               (* 　Ａ　 *)
       {$APPTYPE CONSOLE}
       uses SysUtils;

       procedure Recursive1(M,N : Integer; Depth : Integer);
         begin
           WriteLn('':5*Depth, 'Rec(', M, ',', N, ') に入った');
           if M<N then Recursive1(M+1,N,Depth+1);
           WriteLn('':5*Depth, 'Rec(', M, ',', N, ') から出る');
         end; {Recursive1}

       procedure Recursive5(M,N : Integer; Depth : Integer);
         begin
           WriteLn('':5*Depth, 'Rec(',  M, ',', N, ') に入った');
           if 2*M  <=N then Recursive5(2*M  ,N,Depth+1);
           WriteLn('':5*Depth, 'Rec(',  M, ',', N, ') の途中');
           if 2*M+1<=N then Recursive5(2*M+1,N,Depth+1);
           WriteLn('':5*Depth, 'Rec(',  M, ',', N, ') から出る');
         end; {Recursive5}

       begin
         Recursive1(1,5,0);
         WriteLn;
         Recursive5(1,10,0);
         WriteLn;
         ReadLn;
       end.

       (******************************************************************)
       上のプログラムを実行し，その出力を参考にして，
       下のプロシージャを実行するとどんな出力がされるか，
       紙の上で考えましょう．

       procedure Recursive2(M,N : Integer);
         begin
           Write(M:3);
           if M<N then Recursive2(M+1,N);
         end; {Recursive2}

       procedure Recursive3(M,N : Integer);
         begin
           if M<N then Recursive3(M+1,N);
           Write(M:3);
         end; {Recursive3}

       procedure Recursive4(M,N : Integer);
         begin
           Write(M*2:3);
           if M<N then Recursive4(M+1,N);
           Write(M*2+1:3);
         end; {Recursive4}

       procedure Recursive6(M,N : Integer);
         begin
           Write(M:3);
           if 2*M  <=N then Recursive6(2*M  ,N);
           if 2*M+1<=N then Recursive6(2*M+1,N);
         end; {Recursive6}

       procedure Recursive7(M,N : Integer);
         begin
           if 2*M  <=N then Recursive7(2*M  ,N);
           Write(M:3);
           if 2*M+1<=N then Recursive7(2*M+1,N);
         end; {Recursive7}

       procedure Recursive8(M,N : Integer);
         begin
           if 2*M  <=N then Recursive8(2*M  ,N);
           if 2*M+1<=N then Recursive8(2*M+1,N);
           Write(M:3);
         end; {Recursive8}